Les Macros

Pas indispensables jusqu'à un certain niveau, les macros n'en sont pas moins un moyen simple d'améliorer son expérience de jeu et de se simplifier la vie


Sans trop s'étendre sur la question (suivra le lien d'un guide, mais il est long, peu de gens prennent le temps de lire), voici les grandes lignes


Il est possible d'assigner un nombre conséquent de sorts différents à une même touche, ceci soit via touches modificatrices, Alt Ctrl et Shift ; soit via conditions directes, votre posture ou forme par exemple ; soit via conditions indirectes, la cible est elle amie ou ennemie, est elle votre focus, tel personnage, etc 

exemple

Code:

/cast [mod:alt, @focus, harms] sort qui fait mal; [mod:alt, @focus, help] sort qui soigne; [mod:ctrl, @player] sort qui soigne; [harms] sort qui fait mal; [help] sort qui soigne

il faut lire cette macro comme une suite de condition mises sous [crochets] et séparées par des point virgules, si la condition n'est pas remplie alors le jeu ira chercher la prochaine et ainsi de suite,
si la touche alt est enfoncée, qu'un focus existe, et qu'il est ennemi, le sort qui fait mal partira sur le focus ennemi, sinon le jeu ira voir si la prochaine condition est plus pertinente,
il vérifiera aslors si la touche alt est enfoncée, si un focus existe, et s'il est allié, si tout est bon le sort de soin partira sur le focus allié, sinon rebelote
la meme chose pour la touche CTRL, le @player signifie "vous meme",
puis si aucune touche n'est enfoncée, il verifiera simplement si la cible est ennemie ou amie et lancera le sort en conséquence, sur votre cible actuelle


autre exemple

Code:

/cast [stance:1] sort cac; [stance:2] sort distance; [stance:3] sort de heal

lance différents sorts en fonction de votre forme ou posture, d'autre conditions du meme genre existent comme savoir si un bouclier est équipé ou non


il est ensuite possible de jouer sur les sorts directement, par exemple le brise genou du guerrier n'est utilisable qu'au cac, alors que charge nécessite une distance d'au moins 8m, rien n’empêche de faire une macro comme celle-ci

Code:

/cast brise-genou
/cast charge

au cac on brisera un genou, à plus de 8m on chargera


ensuite viennent les sorts n’entraînant pas de GCD, comme votre bijou par exemple

Code:

/cast bijou de la grue anorexique
/cast megablast

macros stop casting, pour fakecast notament (ou bien evidement pour les decast, purge &co, fin les trucs ou faut pas attendre), ou simplement bind un /stopcasting sur votre touche reculer si vous ne faites pas de pvp et que escape vous semble trop loin, prefere escape perso

Code:

#showtooltip
/stopcasting
/cast sort a incanter

les castséquence, horribles si mal fichues, fabuleuses si bien fichues
exemple pour sham, si vous avez a nouveau esoin du totem avant la fin de recharge du cd, un petit spam et hop c'est good en toute reactivité

Code:

#showtooltip
/castsequence reset=59 Totem de séisme, appel des éléments

maintenant si vous n'etes pas perdu, voici un guide plus complet

ainsi qu'une bonne base pour avoir des idées : ArenaJunkies (les macros qui s'y trouvent sont en anglais et nécessiteront d’être traduites pour fonctionner avec un client de jeu français)

à noter que l'addon super duper macro vous permet de passer outre la limitation en characters des macros, ainsi que des scripts, et ça c'est du lourd

Macros HUNT

Spammable AotH
--------------
/cast !aspect of the hawk


BW + engi gloves + trinkets + orc racial
--------------
#showtooltip bestial wrath
/use 10
/use 13
/use 14
/cast blood fury
/cast bestial wrath
/cast dust cloud


Interrupt
--------------
#showtooltip counter shot
/stopcasting
/stopcasting
/stopcasting
/stopcasting
/stopcasting
/stopattack
/cast [@focus,exists,harm,nodead][] counter shot


Disengage
--------------
#showtooltip disengage
/stopcasting
/stopcasting
/cast disengage


Feign Death
--------------
#showtooltip feign death
/stopcasting
/stopcasting
/cast feign death


Kill Command current pettarget, or KC + petattack playertarget if pet has no target
--------------
/cast [@pettarget,exists][] kill command
/petattack [@pettarget, noexists]


MD with precedence: target > focus > individual targets name > pet
--------------
#showtooltip misdirection
/cast [@target,help,exists,nodead][@focus,help,exists,nodead][@kazzraki   ,help,exists,nodead][@pet,help,exists,nodead][] misdirection


BM pull macro
--------------
/cast spirit walk
/use [combat] 10
/petattack [combat]
/startattack [combat]
/cast [combat] rabid
/cast [combat] rapid fire
/cast [combat] blood fury
/castsequence reset=5 glaive toss,bestial wrath,kill command,stampede,dire beast,arcane shot,arcane shot


Rabid
--------------
/cast rabid
/use 10


Stampede (not using this as BM)
--------------
#showtooltip stampede
/use 10
/use 13
/use 14
/cast blood fury
/cast rabid
/cast stampede


Cobra & Steady Shot + cancelaura things
--------------
#showtooltip steady shot
/cancelaura deterrence
/cancelaura hand of protection
/cancelaura body and soul
/cancelaura bat costume
/cast !steady shot


Tranq Shot with precedence: Focus > Target
--------------
#showtooltip tranquilizing shot
/cast [@focus,exists,harm,nodead][] tranquilizing shot


Toggle focus macro
--------------
/focus [noexists]
/stopmacro [noexists]
/cleartarget
/targetlasttarget
/tar [@focus,exists]
/targetlasttarget [@focus,exists]
/focus
/targetlasttarget [noexists]


Healthstone
--------------
#showtooltip item:5512
/stopcasting
/stopcasting
/use healthstone


Spirit Mend with precedence: Target > Player
--------------
/cast [@target,help,nodead][@player] spirit mend


Ultraxion button
--------------
/stopcasting
/stopcasting
/click ExtraActionButton1


Use belt
--------------
/cancelaura stampeding roar
/cancelaura dash
/cast 6


Use cloak
--------------
/cast 15

me suis motivé a refaire mon set de macros targetting

Skull

Code:

/run SetRaidTarget("target",

Assist(é), marche avec un nom de joueur etc

Code:

/assist [@focus]

Extrabouton

Code:

/stopcasting
/tar [@mouseover]
/click ExtraActionButton1
/targetlasttarget
/startattack

Marques au sol

Code:

/click CompactRaidFrameManagerDisplayFrameLeaderOptionsRaidWorldMarkerButton
/click [mod:alt] DropDownList1Button2; [mod:shift] DropDownList1Button3; [mod:ctrl] DropDownList1Button4; DropDownList1Button1

Target un mob en particulier

Code:

/targetexact unijambiste de l'aigle grelottant
/startattack

Swap target <> focus, juste magique celle là

Code:

/cleartarget [@target,dead]
/clearfocus [@focus,dead]
/tar focus
/cleartarget [@focus,noexists]
/targetlasttarget
/focus target
/targetlasttarget